修改类和窗体以便向分隔文本文件回写记录

更新记录或添加新记录之后，您就可以将更改回写到用作数据识别类数据源的分隔文本文件中。还可以将公有方法添加到将记录写入文件的类中，然后在您的应用程序中调用该方法。

本主题显示了如何修改 CustomerDataSource 类，以提供将记录回写到 Customers.txt 文件中的公有方法，以及如何在客户地址窗体中调用方法。

要修改类和窗体，以将所有记录回写到分隔文本文件中，请按照以下步骤执行：

1. 在类中创建将记录写入文件的公有方法。
   
   
2. 在窗体中创建将记录写入文件的命令按钮。

注意   本主题是帮助您创建一个与分隔文本文件中的数据交互的简单数据库应用程序系列中的一部分。与ASCII 文本文件中的数据交互是第一部分。

在类中创建将记录回写到文件的公有方法

通过将子程序添加到类中，您可以为使用该类作为数据源的应用程序提供公有方法。例如，可以在 CustomerDataSource 类中创建将 rsCustomers 记录集中的当前记录写入 Customers.txt 分隔文本文件中的公有方法。文本文件就会包括您对记录集所作的任何更改和添加。

要创建公有 WriteToFile 方法，请添加下列代码到 CustomerDataSource 类:

Public Sub WriteToFile()

   Dim fld As ADODB.Field
   Dim strRow As String
   Dim strField As String

   Open "Customers.txt" For Output As #1

   With rsCustomers

      .MoveFirst
      Do While Not .EOF
         For Each fld In .Fields
            ' 如果字段有值，则添加引号。
            If Len(fld.Value) > 0 Then
               strField = Chr(34) & fld.Value & Chr(34)
            Else
               strField = ""
            End If
            '在输出字符串中添加字段值和 tab 分隔符。
            strRow = strRow & strField & Chr(9)
         Next
         '去掉最后的 tab 字符。
         strRow = Left(strRow, Len(strRow) - 1)
         '打印输出字符串。
         Print #1, strRow
         strRow = ""
      .MoveNext
      Loop
   End With
   Close

End Sub

在窗体中创建将记录写入文件的命令按钮

一旦您在数据识别类中创建了公有方法，便可以在任何需要同样功能的应用程序中使用它。例如，通过创建将记录写入分隔文本文件的公有方法，可以很容易地在客户地址窗体中创建 WriteToFile 按钮。命令按钮需要一行代码。

要创建一个 WriteToFile 按钮，请添加一个命令按钮到窗体中，并将其 Caption 和 Name 属性更改为 WriteToFile。然后将下列代码添加到命令按钮的 WriteToFile_Click 事件过程中：

objDataSource.WriteToFile

代码使用了您为 CustomerDataSource 类创建的 WriteToFile 方法。

您可能希望当用户在窗体中输入数据时隐藏WriteToFile 按钮。要在输入数据时隐藏命令按钮，请将下列代码添加到 DataEntry_Click 事件过程中：

Me.WriteToFile.Visible = False

如果您在用户输入数据时隐藏了 WriteToFile 按钮，要在当用户查看数据时使其可见。要这样做，请将下列代码添加到 ViewData_Click 事件过程中：

Me.WriteToFile.Visible = True

步骤

本主题是帮助您创建一个与 tab 分隔文本文件中的数据交互的简单数据库应用程序系列的结尾。要从头开始，请参阅与 ASCII 文本文件中数据的交互。

详细信息 有关数据源的详细信息，请参阅《部件工具指南》中的创建数据源。