使用 ActiveX 部件

使用 ActiveX 部件提供的对象与操作其他对象的方法十分相似。首先将一个对象引用赋值给变量，然后编写使用对象的方法、属性与事件的代码。但是，在操作部件提供的对象时，还是有一些事情需要注意的。

这个主题综述了操作部件提供的对象的顶层任务，及使用 ActiveX-enabled 应用程序中的对象的例子。关于每个任务的细节，请参阅每个任务项目下描述的有关主题。

要使用 ActiveX 部件提供的大多数对象，请按照以下步骤执行：

1. 创建对要使用的对象的引用。如何做这件事，取决于对象的类型及 ActiveX 部件是否提供类型库。

   关于更详细的信息   请参阅本章后面的“创建对对象的引用”。

2. 用对象的方法、属性与事件编写代码。

   关于更详细的信息   请参阅本章后面的“使用对象的属性、方法与事件”。

3. 当对象使用完毕后，将其释放。

   关于更详细的信息   请参阅本章后面的“释放 ActiveX 部件”。

4. 创建错误处理程序
   
   
5. 关于更详细的信息   请参阅本章后面的“在 ActiveX 部件中处理运行时错误”。

例如，假设已经创建一个包含三个文本框 (Text1，Text2，Text3) 和一个命令按钮 (Command1) 的窗体，并在工程中添加了对 Microsoft Excel 8.0对象库的引用。接着，可将代码加到命令按钮的Command1_Click 事件过程中，该过程用 Microsoft Excle Formula 方法将 Text1 和 Text2 中的两个数相加，在 Text3 中显示结果。（为避免类型不匹配错误，可能要删除每个文本框的缺省文本值，方法是将其 Text 属性置为空字符串）：

Private Sub Command1_Click()
   '为 Microsoft Excel 应用程序、工作簿
   '和工作表对象声明对象变量。
   Dim xlApp As Excel.Application
   Dim xlBook As Excel.Workbook
   Dim xlSheet As Excel.Worksheet

   '将对象引用赋值给这些变量。
   '用 Add方法 创建新的工作簿和工作表对象。
   Set xlApp = New Excel.Application
   Set xlBook = xlApp.Workbooks.Add
   Set xlSheet = xlBook.Worksheets.Add
   
   '将文本框中的值赋给Microsoft Excel 单元。
      xlSheet.Cells(1, 1).Value = Text1.Text
   xlSheet.Cells(2, 1).Value = Text2.Text
   
   '用 Formula 方法将 Microsoft Excel 中的值相加。
      xlSheet.Cells(3, 1).Formula = "=R1C1 + R2C1"
   Text3.Text = xlSheet.Cells(3, 1)
   
   '保存工作表
   xlSheet.SaveAs "c:\Temp.xls"
   ' 关闭工作表。
   xlBook.Close

   '用 Quit 方法关闭 Microsoft Excel
   xlApp.Quit
   
   '释放对象
   Set xlApp = Nothing
   Set xlBook = Nothing
   Set xlSheet = Nothing
End Sub

为了简单起见，这个例子不包括错误处理。然而，在使用由 ActiveX 部件提供的对象的应用程序中，推荐您包括错误处理。